うちで使ってるやつだと、どーもネットワークに高負荷かけると、一時的に接続付加になるようなのですが、解決しておりません。AMDはIO周りが良いはずなのに、ML110のほうがまともなのが解せない。

結果、IO負荷があまりかからない方向で使っておりますが、ネットワーク越しにファイルコピーするときは ionice -c3 でごまかしております。

※動作を保障するものではありませんので、苦情は受け付けません！

@echo off
@rem author: 英太郎 eitaro+eitaro.cpmstaff.com
@rem usage: mux.bat [展開するフォルダ名]
@rem オプションは通常無しで動きます。
@rem ex) mux.bat d:\mp4

rem 遅延環境変数の展開
setlocal enabledelayedexpansion

rem mkvtoolnix をインストール http://www.bunkus.org/videotools/mkvtoolnix/downloads.html
rem コマンド類はパスの通った場所にコピーしてあれば修正不要

rem GBの場所 ファイルをごみ箱へ移動するスクリプト http://www.comona.co.jp/gbdl.html
set GB="GB.exe"

rem mp4box.exe DtsEditに同梱
set mp4box="mp4box.exe"

rem DtsEditの場所 http://seraphy.fam.cx/~seraphy/pg_mod.html
set DtsEdit="DtsEdit.exe"

rem tc2mp4Modの場所 http://zoome.jp/VFR_maniac/diary/6
rem tc2mp4の場所 ※使っていません
rem set tc2mp4="tc2mp4Mod.exe"

rem #### optput dir
if not "%1" == "" (
	set optput=%1
) else (
	set optput=mp4
)

rem #### optput dir 作成
if not exist !optput! (
	mkdir !optput!
	if errorlevel 1 (
		echo "!optput!"が作成できません。
		goto error
	)
)

rem #### par
if not "%2" == "" (
	set par=-par 1=%2
) else (
	echo [default]            1:1
	echo [1] 720x480 to 16/9 32:27
	echo [2] 720x480 to  4/3  8:9
	echo [3] 704x480 to  4/3  10:11
	echo [0] no change
	set /p INPAR="par を入力してください "
	if        "!INPAR!" == ""  ( set par=-par 1=1:1
	) else if "!INPAR!" == "1" ( set par=-par 1=32:27
	) else if "!INPAR!" == "2" ( set par=-par 1=8:9
	) else if "!INPAR!" == "3" ( set par=-par 1=10:11
	) else if "!INPAR!" == "0" ( set par=
	)
)

set INP=
for %%i in (*.mp4 *.h264) do (
	set video="%%~ni.vfr.mp4"
	set timecode="%%~ni.txt"
	set newmp4="!optput!\%%~ni.mp4"

	rem videoname
	set h264=
	set rawvideo="%%~ni.mp4"
	if not exist !rawvideo! (
		set h264="%%~ni_track1.h264"
		if not exist !h264! (
			set h264="%%~ni.h264"
		)
	)

	rem audioname
	if exist "%%~ni.m4a" (
		set audio="%%~ni.m4a"
	) else if exist "%%~ni_track2.m4a" (
		set audio="%%~ni_track2.m4a"
	) else if exist "%%~ni_audio.m4a" (
		set audio="%%~ni_audio.m4a"
	) else if exist "%%~ni.aac" (
		set audio="%%~ni.aac"
	) else if exist "%%~ni_track2.aac" (
		set audio="%%~ni_track2.aac"
	) else if exist "%%~ni_audio.aac" (
		set audio="%%~ni_audio.aac"
	) else (
		set audio=""
	)

	echo ---- audio:!audio!
	echo ++++ !newmp4! 作成

	if not "!INP!" == "y" (
		if exist !newmp4! (
			set /p INP="!newmp4! ファイルが存在します。続行しますか？[N/y] "
			if not "!INP!" == "y" (
				set INP=
				goto end
			)
		)
	)

	if not "!h264!" == "" (
		!mp4box! -fps 23.976 -add !h264! -new !rawvideo!
		if not errorlevel 1 (
			del !h264!
		) else (
			goto error
		)
	)

	rem create vfr
	if exist !timecode! (
		echo -- create vfr
		rem !tc2mp4! -i !rawvideo! -t !timecode! -o !video!
		!DtsEdit! -tc !timecode! !rawvideo! -o !video!
		if not errorlevel 1 (
			rem ファイル削除
			del !rawvideo!
			!GB! !timecode!
		) else (
			goto error
		)
		set rawvideo=!video!
	)

	rem mux
	if exist !audio! (
		echo -- create mp4
		echo -- command -- !mp4box! -fps 23.976 !par! -add !rawvideo!#video -add !audio! -new !newmp4!
		!mp4box! -fps 23.976 !par! -add !rawvideo!#video -add !audio! -new !newmp4!
		if not errorlevel 1 (
			rem ファイルをごみ箱へ http://www.comona.co.jp/gbdl.html
			del !audio!
			del !rawvideo!
		) else (
			goto error
		)
	)
)
goto end

:error
echo "エラーが発生した為停止しました。"
pause
goto end

:end
echo -- 終了
endlocal

※動作を保障するものではありませんので、苦情は受け付けません！

@echo off
@rem author: 英太郎 eitaro+eitaro.cpmstaff.com
@rem usage: demux.bat [mkv用オーディオパート番号 展開するフォルダ名]
@rem オプションは通常無しで動きます。
@rem ex) demux.bat 2 d:\raw

rem 遅延環境変数の展開
setlocal enabledelayedexpansion

rem mkvtoolnix をインストール http://www.bunkus.org/videotools/mkvtoolnix/downloads.html
rem コマンド類はパスの通った場所にコピーしてあれば修正不要

rem mp4box の場所 DtsEditに同梱
set mp4box="mp4box.exe"

rem DtsEdit の場所 http://seraphy.fam.cx/~seraphy/pg_mod.html
set DtsEdit="DtsEdit.exe"

rem #### オーディオパート番号
if not "%1" == "" (
	set audiopart=%1
) else (
	set audiopart=2
)

rem #### optput dir
if not "%2" == "" (
	set optput=%2
) else (
	set optput=raw
)

set INP=
for %%i in (*.mp4 *.avi *.mkv) do (
	set timecode="!optput!\%%~ni.txt"
	set timecodename="%%~ni.txt"
	set newmp4="!optput!\%%~ni.mp4"
	set temp="temp0099.mkv"

	echo !newmp4! 作成

	if not "!INP!" == "y" (
		if exist "!newmp4!" (
			set /p INP="!newmp4! ファイルが存在します。続行しますか？[N/y] "
			if not "!INP!" == "y" (
				goto end
			)
		)
	)

	rem #### optput dir 作成
	if not exist !optput! (
		mkdir !optput!
		if ERRORLEVEL 1 (
			echo "!optput!"が作成できません。
			goto error
		)
	)

	rem timecode
	if "%%~xi" == ".mp4" (
		!DtsEdit! "%%i"
		if ERRORLEVEL 1 ( goto error )
		if exist !timecode! ( del !timecode! )
		move "%%~ni.mp4_timecode.txt" "!optput!"
		rename "!optput!\%%~ni.mp4_timecode.txt" !timecodename!
		if ERRORLEVEL 1 ( goto error )
	) else if "%%~xi" == ".mkv" (
		mkvextract timecodes_v2 "%%i" 1:!timecode!
		if ERRORLEVEL 1 ( goto error )
	) else if "%%~xi" == ".avi" (
		mkvmerge "%%i" -o !temp!
		mkvextract timecodes_v2 !temp! 1:!timecode!
		del !temp!
	) else (
		echo "%%~xi" type unknown!
		goto end
	)

	rem rawvideo
	if "%%~xi" == ".mkv" (
		mkvextract tracks "%%i" 1:"%%~ni.h264" --no-ogg
		!mp4box! -fps 23.976 -add "%%~ni.h264" -new !newmp4!
		if ERRORLEVEL 1 (
			echo %ERRORLEVEL%
			!mp4box! -aviraw video "%%~ni.h264"
			if ERRORLEVEL 1 ( goto error )
			!mp4box! -add "%%~ni_video.cmp" -fps 23.976 -new !newmp4!
			if ERRORLEVEL 1 ( goto error )
		)
	) else (
		if "%%~xi" == ".avi" (
			!mp4box! -aviraw video "%%i"
		) else (
			!mp4box! -raw 1 "%%i"
		)
		if ERRORLEVEL 1 ( goto error )
		rem mux
		if exist "%%~ni_video.cmp" (
			!mp4box! -add "%%~ni_video.cmp" -fps 23.976 -new !newmp4!
		) else if exist "%%~ni_video.h264" (
			!mp4box! -add "%%~ni_video.h264" -fps 23.976 -new !newmp4!
		) else if exist "%%~ni_track1.cmp" (
			!mp4box! -add "%%~ni_track1.cmp" -fps 23.976 -new !newmp4!
		) else if exist "%%~ni_track1.h264" (
			!mp4box! -add "%%~ni_track1.h264" -fps 23.976 -new !newmp4!
		) else (
			echo video type unknown
			goto error
		)
		if ERRORLEVEL 1 ( goto error )
	)
	if exist "%%~ni.h264" ( del "%%~ni.h264" )
	if exist "%%~ni_track1.cmp" ( del "%%~ni_track1.h264" )
	if exist "%%~ni_track1.h264" ( del "%%~ni_track1.h264" )
	if exist "%%~ni_video.cmp" ( del "%%~ni_video.cmp" )
	if exist "%%~ni_video.h264" ( del "%%~ni_video.h264" )

	rem audio
	if "%%~xi" == ".mkv" (
		mkvextract tracks "%%i" !audiopart!:"!optput!\%%~ni.ogg"
		if ERRORLEVEL 1 ( goto error )
	) else (
		if "%%~xi" == ".mp4" (
			!mp4box! -raw 2 "%%i"
		) else if "%%~xi" == ".avi" (
			!mp4box! -aviraw audio "%%i"
		)
		if ERRORLEVEL 1 ( goto error )
		if exist "%%~ni_audio.ac3" (
			if exist "!optput!\%%~ni_audio.ac3" ( del "!optput!\%%~ni_audio.ac3" )
			move "%%~ni_audio.ac3" "!optput!\%%~ni.ac3"
		) else if exist "%%~ni_audio.aac" (
			if exist "!optput!\%%~ni_audio.aac" ( del "!optput!\%%~ni_audio.aac" )
			move "%%~ni_audio.aac" "!optput!\%%~ni.aac"
		) else if exist "%%~ni_track2.ac3" (
			if exist "!optput!\%%~ni_track2.ac3" ( del "!optput!\%%~ni_track2.ac3" )
			move "%%~ni_track2.ac3" "!optput!\%%~ni.ac3"
		) else if exist "%%~ni_track2.aac" (
			if exist "!optput!\%%~ni_track2.aac" ( del "!optput!\%%~ni_track2.aac" )
			move "%%~ni_track2.aac" "!optput!\%%~ni.aac"
		)
	)
	if ERRORLEVEL 1 ( goto error )
)
goto end

:error
echo "エラーが発生した為停止しました。"
pause
goto end

:end
echo -- 終了
endlocal
set INP=

DtsEdit.exe -tc timecode.txt source.mp4 -o new.mp4

一部フレームレートがおかしくなる部分もあるようですが、概ねちゃんと修正してくれるみたいですね。

mp4にこだわらないなら、mkvmergeでmkv化しちゃえば、こっちはエラーがあったタイムコードでも読んでくれました。

まずエクスプローラーですが、ツリー表示の展開をONで使っているのですが、フォルダを展開するとカレントフォルダが下のほうに行ってしまって見失う。ツリー部のサイズ変更すると全部のウインドウが勝手に変わる。ファイル名などの表示幅を広げても、別なフォルダを見た後戻ると戻ってる。。。など、勝手に変更されることが多すぎてかえって使いづらく感じます。

どーも目線移動をかってにされるのがイライラの最大の原因なので、カーソル位置を基準に色々やってくれるならまだ耐えられるのですが、ファイル操作作業が多いと嫌になります。

後は、ファイルタイプの関連付けでアイコンの変更ができない。このくらい変更させてくれ！

良くなっているところも多いのに、親切が過ぎてイライラさせられる感じが強いですね。あんまり干渉してほしくない部分とか、フォルダタイプ勝手に変えないでほしいとか、もう少しプロ向け？の設定をさせてほしい（笑うところじゃないですよ）。

全体的に初心者に優しくプロに厳しい作りになっているのは気のせいでしょうか？べた褒めな記事も多いですが、いっそLinux使うかと思っちゃいます。細かい制限が多いんですよね。

設定とか変に隠さないで、手軽にできるモードもあるべきだと思うんですがどうでしょう？

これは、私の都合ですが、aviファイルから直接timecodeを取得するソフトを探すのが面倒だったので、timecodeはmkv化して取得しています。使うツールももｍｋｖ用と同じなので、ツールはこちらを参考にしてください。

では、分離手順。

mkvファイル作成
mkvmerge "source.avi" -o "temp.mkv"

タイムコード取得
mkvextract timecodes_v2 "temp.mkv" 1:"timecode.txt"

rawvideo取得
mp4box -aviraw video "source.avi"

24fpsでMUX(DX50)
mp4box -add "source_video.cmp" -fps 23.976 -new "rawvideo.mp4"

h264のときは
mp4box -add "rawvideo.h264" -fps 23.976 -new "rawvideo.mp4"

rawaudio取得
mkvextract tracks "source.mkv" 2:"rawaudio.ogg"

分離したら、エンコードします。
以下mkv編と同じ（手抜き）。

avidemux.batをおいておきます。

MediaCoderはフロントエンドなので、使うエンコーダーやデコーダー、設定で色々できるので、気に入った設定が見つかるまでやることが多いですが、慣れると使いやすいかなと思います。

お手軽一発ではないので、いじるのが好きな人向けでしょうかね？

それから、原因がよくわからないのですが、オーディオのエンコ時、途中で切れたりします。このときは、オーディオのみ再度エンコードして、手動でMUXするのが早くて簡単です。

動画のエンコードにはMediaCoderを使用しています。

あっと、いい忘れましたが、mkvファイルの中身は h264 + audio の構成とします。それ以外の構成は私にはわかりかねます。

必要なソフトですが、まず、MKVtoolnixをインストールしておいてください。

次に、GB.exe（ファイルをゴミ箱へ入れるソフト）と mp4box.exe、tc2mp4.exe か tc2mp4Mod.exe （私は tc2mp4Modを使用してます）が必要になります。これらをパスの通った場所へコピーしておいてください。

それではまずファイルの分離をします。

タイムコード
mkvextract timecodes_v2 "source.mkv" 1:"timecode.txt"

.h264
mkvextract tracks "source.mkv" 1:"rawvideo.h264" --no-ogg

cfr mp4 作成
mp4box -add "rawvideo.h264" -fps 23.976 -new "rawvideo.mp4"

オーディオ
mkvextract tracks "source.mkv" 2:"rawaudio.ogg"

順にタイムコードの分離、h264ソースの分離、h264ソースを固定フレームレートでmp4ファイル作成、オーディオファイルの分離を行っています。

次にエンコードをします。これはmp4ファイルとoggファイルをそれぞれエンコードすればOKです。

エンコが終わったらMUXします。

エンコード終了ファイル置き場へタイムコードファイルを移動し、

vfr作成
tc2mp4Mod -i "cfrvideo.mp4" -t "timecode.txt" -o "vfrvideo.mp4"

オーディオmux
mp4box -add "vfrvideo.mp4" -add "audio.m4p" -new "video.mp4"

で可変フレームレートなmp4ファイルの出来上がりです。ソースのビットレートなどは動画サイズや好みに合わせて変更してください。

demux と mux は、それぞれ .mkv .avi .mp4 ファイルのある場所で実行すれば連続で処理してくれます。処理後ファイルがゴミ箱に入るものもありますので、ディスクの空き容量には十分注意してください。

mux.bat は、アスペクト比変更できますので、アスペクト比が変になったり間違ったりした場合に一括で変更できます。オプション無しで聞いてきますので、 1:1 （ピクセル比1/1）、オプションは 32:27 等指定します。

アスペクト比の計算には AspectCalc が便利ですよ！

あと、HTMLHelpファイルで、レンダリングが一部崩れます。実用上問題無いのでそのまま使ってますが、βとしてはよさげな感じですね。私は特に拡張機器を使用してないので問題は少ないと思いますが、タスクバーは非常に気に入ってます。

他にはVMWareServerを使用していますが、IEで開けない問題もローカルインターネットサイトへパスを追加することによって動くことがわかり、こちらも実用上問題なく使用できてます。

現状でいまいちうまくいかないのが、VMWare Serverでの管理画面と、Wordpressもうまく動かないです。

その他での不具合は今のところあまり無いようです。使い勝手的には、タスクバーがかなりよい感じなので、しばらく使ってみようと思います。

※この記事はFirefoxで書いてます。